Section 13.2 (6th edition)

load(draw);

Example 1. (a) Find the derivative of the curve [1+t^3,t*exp(-t),sin(2*t)]

rr: [1+t^3,t*exp(-t),sin(2*t)];

drr: diff(rr, t);

(b) Formulate the unit tangent vector, and evaluate it at t=0. Note the statement after the comma "," will substitutes the parameter in formula with value.

drr / sqrt(drr . drr), t=0;

Example 3. Find the tangent line to the curve [2*cos(t),sin(t),t] at t = %pi/2.

rr: [2*cos(t),sin(t),t];

drr: diff(rr, t);

L: rr + s*drr, t=%pi/2;

draw3d(xlabel="X", ylabel="Y",
    color=blue, parametric(rr[1],rr[2],rr[3],t,0,2*%pi),
    color=red, line_width=2, parametric(L[1],L[2],L[3],s,-2,2));

Example 4. Integrate the curve [2*cos(t),sin(t),2*t] from 0 to %pi/2.

rr: [2*cos(t),sin(t),2*t];

RR: integrate(rr, t);

at(RR,t=%pi/2) - at(RR,t=0);

integrate(rr, t, 0, %pi/2);

*Exercise 18: Find the unit tangent vector to [4*sqrt(t),t^2,t] at t=1

drr: diff([4*sqrt(t),t^2,t], t);

TT: drr / sqrt(drr . drr), t=1;

*Exercise 24: Find the equation of the tangent line (itself parametrized
with s) to the curve [exp(t), t*exp(t), t*exp(t^2)] (parametrized by t) at t=0.

rr: [exp(t), t*exp(t), t*exp(t^2)];

drr: diff(rr, t);

[x,y,z] = rr + s*drr, t=0;

*Exercise 34: Integrate the curve [0,4/(1+t^2),2*t/(1+t^2)] from t=0 to t=1

integrate([0,4/(1+t^2),2*t/(1+t^2)],t,0,1);

*Exercise 46: Differentiate the cross product of [sin(t),cos(t),t] and [t,cos(t),sin(t)]

load(vect);

uu: [sin(t),cos(t),t]; vv: [t,cos(t),sin(t)];

cross: express(uu~vv);

diff(cross, t);

express(diff(uu,t)~vv + uu~diff(vv,t));